The following script can be handy if you want to deploy certain computer model specific software within a scripted installation on Dell Kace 2000. It might be usefull for other things as well (Windows Deployment Services maybe) if you want to check if it applies before applying the software or script.

@ECHO OFF
REM Obtain Computer Model information from WMI, this is done in two ways, check output for
REM both to which applies best, for example 'model' works best with HP and 'version' works
REM best with Lenovo. If something  applies to all computers from a single brand 'Manufacturer'
REM can be used.

REM Version 1.1, Added support for model and manufacturer

set model=
set version=
set manufacturer=

for /F "tokens=2 delims='='" %%j in ('wmic computersystem get model /value') do set model=%%j
for /F "tokens=2 delims='='" %%j in ('wmic csproduct get version /value') do set version=%%j
for /F "tokens=2 delims='='" %%j in ('wmic computersystem get manufacturer /value') do set manufacturer=%%j

REM Enter the Computer Models for which the package should apply below, one per line
REM Change the 'if' statement to what works to detect the right hardware, the above 'wmic'
REM commands can be run on the hardware to determine what is the best option.

If "%model%" == "HP EliteBook 2560p" GOTO INSTALL
If "%model%" == "HP EliteBook 8460p" GOTO INSTALL
If "%model%" == "HP EliteBook 8560p" GOTO INSTALL

GOTO GOODBYE

:INSTALL

REM Enter Command Line for Silent Installation below

launcher /S

EXIT

:GOODBYE

EXIT

If you want to check what to use, just putting the wmic commands into a batch file should give you the right amount of info which of the checks would work for the computer you want to deploy:

@echo off
wmic computersystem get model /value
wmic csproduct get version /value
wmic computersystem get manufacturer /value